Calculate Running Count and Running Total - Excel

In Excel, there are various techniques to compute Running Count and Running Total. These techniques can be divided into two categories: one that manages only ranges and another that can handle both ranges and arrays.

Today, I will demonstrate techniques for both categories.

Methods to calculate Running Count and can only handle range:

Method-1:

=COUNTIF(OFFSET(B3,,,SEQUENCE(ROWS(B3:B13))),B3:B13)

Method-2:

=COUNTIF($B$3:B3,B3)

Drag this formula down.

Method-3:

=MAP(B3:B13,LAMBDA(x,SUM(N(B3:x=x))))

Method-4:

=MAP(B3:B13,LAMBDA(a,COUNTIF(B3:a,a)))

Methods to calculate Running Count and can handle Arrays:

Method-1:

=LET(x,ArrayOfName,s,SEQUENCE(ROWS(x)),BYROW((x=TOROW(x))*(s>=TOROW(s)),SUM))

Method-2:

=LET(a,ArrayOfName,MAP(SEQUENCE(ROWS(a)),LAMBDA(x,SUM(--(TAKE(a,x)=INDEX(a,x))))))

Methods to calculate Running Total and can only handle range:

Method-1:

=SUMIF(OFFSET(E3,,,SEQUENCE(ROWS(E3:E13))),E3:E13,F3)

Method-2:

=MAP(E3:E13,F3:F13,LAMBDA(a,b,SUMIF(E3:a,a,F3:b)))

Method-3:

=MAP(E3:E13,LAMBDA(e,SUM((E3:e=e)*N(+F3:e))))

Methods to calculate Running Total and can handle Arrays:

Method-1:

=LET(x,ArrayOfName,y,ArrayOfSalesNum,s,SEQUENCE(ROWS(x)),BYROW((x=TOROW(x))*(s>=TOROW(s))*TOROW(y),SUM))

Method-2:

=LET(a,ArrayOfName,b,ArrayOfSalesNum,MAP(SEQUENCE(ROWS(a)),LAMBDA(x,SUM((TAKE(a,x)=INDEX(a,x))*TAKE(b,x)))))